How to output Microsoft Word heading styles

[kcann]

Hello!

I need to end up with Word output that uses Word's built-in heading styles (Heading 1, Heading 2, etc.) in order to use the Word navigation pane to display topics. Has anyone figured out how to do this?

Thanks!

KC

[Nita Beck]

To the best of my knowledge, Flare does not offer a means to map its heading styles to Word heading styles when generating Word output. The best solution I've found is to search-and-replace the Flare heading styles for Word heading styles in the generated Word document. Although I haven't done this myself, it's probably easy enough to create some Word macros in order to run the same search-and-replace swaps whenever needed.

[wclass]

Flare won't output to the standard Word styles - you can raise a bug like the rest of us:
https://www.madcapsoftware.com/feedback/bugs.aspx

I use the Find/Replace method once I have generated the Word doc (pretty quick to change H1 to Heading 1, H2 to Heading 2 and so on). I have a macro to do this - let me know if you'd like a copy and I'll send it when I'm back at my desk.

[mblackburn]

Hi Margaret -- If you have that macro available, would you send it to me also? Thanks!

[wclass]

Here is the macro for converting Hx to "Heading x" styles.
It does not handle sub-classes (for example, styles like "h1.xyz")

Add this code to a Word template (normal.dotm would do)

Code: Select all

Sub ConvertHeadingsFindReplace()
' This routine searches for styles "Hx" and replaces with standard
' Word heading styles called "Heading x".
' It does this for all 6 levels of heading.
' It sets error checking off so that it skips any heading levels not
' found in the document.

    On Error Resume Next
    
'   Clear the formatting parameters

    Selection.Find.ClearFormatting
    Selection.Find.Replacement.ClearFormatting
    With Selection.Find
        .Text = ""
        .Replacement.Text = ""
        .Forward = True
        .Wrap = wdFindContinue
        .Format = True
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With

'   Run Find/Replace on heading levels.

    Selection.Find.Style = ActiveDocument.Styles("h1")
    Selection.Find.Replacement.Style = ActiveDocument.Styles("Heading 1")
    Selection.Find.Execute Replace:=wdReplaceAll
    
    Selection.Find.Style = ActiveDocument.Styles("h2")
    Selection.Find.Replacement.Style = ActiveDocument.Styles("Heading 2")
    Selection.Find.Execute Replace:=wdReplaceAll

    Selection.Find.Style = ActiveDocument.Styles("h3")
    Selection.Find.Replacement.Style = ActiveDocument.Styles("Heading 3")
    Selection.Find.Execute Replace:=wdReplaceAll
    
    Selection.Find.Style = ActiveDocument.Styles("h4")
    Selection.Find.Replacement.Style = ActiveDocument.Styles("Heading 4")
    Selection.Find.Execute Replace:=wdReplaceAll

    Selection.Find.Style = ActiveDocument.Styles("h5")
    Selection.Find.Replacement.Style = ActiveDocument.Styles("Heading 5")
    Selection.Find.Execute Replace:=wdReplaceAll
    
    Selection.Find.Style = ActiveDocument.Styles("h6")
    Selection.Find.Replacement.Style = ActiveDocument.Styles("Heading 6")
    Selection.Find.Execute Replace:=wdReplaceAll

End Sub

[Msquared]

Thanks very much for making this available Margaret.

Writing a macro to post-process Flare's output styles for Word to proper Word styles has been on my list of things to do for a long time. This will give me enough of a start to finish it myself.

One of the first feature requests I raised was for Flare to allow you to map to Word output styles, which is something that R***help does really well. However, in 18 months of Flare use, I've managed without Word output so far, since the PDF output is so good. But sooner or later, a SME is going to ask for Word content to review, so I really should get on and sort it.